语言的规范文档要怎么写？

Miu.C

RT,Thanks.

Miu.C

8 - The Complete Syntax of Lua
Here is the complete syntax of Lua in extended BNF. (It does not describe operator precedences.)


        chunk ::= {stat [`;´]} [laststat [`;´]]

        block ::= chunk

        stat ::=  varlist `=´ explist |
                 functioncall |
                 do block end |
                 while exp do block end |
                 repeat block until exp |
                 if exp then block {elseif exp then block} [else block] end |
                 for Name `=´ exp `,´ exp [`,´ exp] do block end |
                 for namelist in explist do block end |
                 function funcname funcbody |
                 local function Name funcbody |
                 local namelist [`=´ explist]

        laststat ::= return [explist] | break

        funcname ::= Name {`.´ Name} [`:´ Name]

        varlist ::= var {`,´ var}

        var ::=  Name | prefixexp `[´ exp `]´ | prefixexp `.´ Name

        namelist ::= Name {`,´ Name}

        explist ::= {exp `,´} exp

        exp ::=  nil | false | true | Number | String | `...´ | function |
                 prefixexp | tableconstructor | exp binop exp | unop exp

        prefixexp ::= var | functioncall | `(´ exp `)´

        functioncall ::=  prefixexp args | prefixexp `:´ Name args

        args ::=  `(´ [explist] `)´ | tableconstructor | String

        function ::= function funcbody

        funcbody ::= `(´ [parlist] `)´ block end

        parlist ::= namelist [`,´ `...´] | `...´

        tableconstructor ::= `{´ [fieldlist] `}´

        fieldlist ::= field {fieldsep field} [fieldsep]

        field ::= `[´ exp `]´ `=´ exp | Name `=´ exp | exp

        fieldsep ::= `,´ | `;´

        binop ::= `+´ | `-´ | `*´ | `/´ | `^´ | `%´ | `..´ |
                 `<´ | `<=´ | `>´ | `>=´ | `==´ | `~=´ |
                 and | or

        unop ::= `-´ | not | `#´


........好麻烦。

游戏之家站长

到策划区有人告诉你

Miu.C

游戏之家站长: Re:语言的规范文档要怎么写？

到策划区有人告诉你

关于语言的怎么轮到策划来告诉我？

航天奇侠

比起自己写代码要简单得多，才一页代码就完成分析过程。

游戏之家站长

伟大的策划!

psic

学习……

CLOD

楼主在没有学完编译原理的情况下，要写个完整的文法不太现实吧。还是按照自己的思路，做一般介绍性的描述比较好

使命召唤

楼主学了文法用来做游戏吗

Miu.C

使命召唤: Re:语言的规范文档要怎么写？

楼主学了文法用来做游戏吗

对啊。免得游戏用硬编码搞得代码乱七八糟性能还低。